@echo off
:: Jedan klik: https://digi-knjigovodstvo.rs/esir-setup
:: Potpuno autonomna ESIR instalacija - bez dolaska u objekat.
::
:: VAZNO 1: ova datoteka NE sadrzi logiku instalacije - samo preuzima i pokrece
:: esir-setup.ps1 sa sajta. Jedini izvor istine je scripts/esir-setup.ps1 u repou
:: (objavi-instalaciju.sh ga objavljuje uz ovaj CMD). Ne prepisuj logiku ovde.
::
:: VAZNO 2: drzi ovu datoteku u ISKLJUCIVO ASCII znakovima (bez crtica-em-dash,
:: bez kvacica). Proveri sa: LC_ALL=C grep -n '[^ -~]' DigiPOS-ESIR-Setup.cmd
:: Posle "chcp 65001" cmd.exe nastavlja citanje po bajt-pomeraju racunatom u
:: staroj kodnoj strani, pa svaki visebajtni znak iznad pomeri parsiranje i
:: raspolovi sledecu komandu ('ho' is not recognized...). Srpski tekst ide u PS1.
chcp 65001 >nul
title DigiPOS ESIR setup
echo === DigiPOS ESIR - instalacija na daljinu ===
echo.

:: PS1_URL se moze nadjacati spolja (test / drugi hosting)
if not defined PS1_URL set "PS1_URL=https://digi-knjigovodstvo.rs/esir-setup/esir-setup.ps1"

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
  "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12;" ^
  "$ps1=Join-Path $env:TEMP ('esir-setup-'+[guid]::NewGuid().ToString('n')+'.ps1');" ^
  "$code=0;" ^
  "try{" ^
  "  Write-Host '[0/4] Preuzimanje instalacione skripte...';" ^
  "  Invoke-WebRequest -Uri $env:PS1_URL -OutFile $ps1 -UseBasicParsing;" ^
  "  if((Get-Content $ps1 -Raw) -notmatch 'DIGIPOS-ESIR-SETUP-V1'){" ^
  "    throw 'Preuzeta datoteka nije DigiPOS instalaciona skripta (hosting je vratio stranicu umesto .ps1). Prekidam.'" ^
  "  };" ^
  "  $global:LASTEXITCODE=0;" ^
  "  & $ps1;" ^
  "  if($null -ne $LASTEXITCODE){$code=$LASTEXITCODE};" ^
  "}catch{" ^
  "  Write-Host $_.Exception.Message -ForegroundColor Red; $code=1;" ^
  "}finally{" ^
  "  Remove-Item $ps1 -Force -ErrorAction SilentlyContinue;" ^
  "};" ^
  "exit $code"

if errorlevel 1 (
  echo.
  echo Instalacija nije uspela. Proverite internet / SmartScreen.
  pause
  exit /b 1
)
echo.
pause